Rename the class you added to clsHolidays and open it, where you should add the following lines of code:

Function Holidays(ByVal StartsOn As String, ByVal EndsOn As String, _
    Location As String) As Variant

    Dim appOutlook      As Outlook.Application
    Dim nSpace          As Outlook.Namespace
    Dim calFolder       As Outlook.MAPIFolder
    Dim calItem         As Outlook.AppointmentItem
    Dim filterItems     As Outlook.Items
    Dim strFilter       As String
    Dim holName         As New Collection
    Dim holDate         As New Collection
    Dim i               As Integer
    Dim aHoliday   

    Set appOutlook = CreateObject("Outlook.Application")
    Set nSpace = appOutlook.GetNamespace("MAPI")
    Set calFolder = nSpace.GetDefaultFolder(olFolderCalendar) 

    strFilter = "[Categories]= 'Holiday' And [Location]= '"
    strFilter = strFilter & Location & "'" & " And [Start]>= '"
    strFilter = strFilter & StartsOn & "'" & " And [End]<= '"
    strFilter = strFilter & EndsOn & "'"

    Set filterItems = calFolder.Items.Restrict(strFilter)
    filterItems.Sort "[Start]", False   

    On Error Resume Next
    For Each calItem In filterItems
        holName.Add calItem.Subject, calItem.Subject
        holDate.Add calItem.Start, CStr(calItem.Start)
    Next   

    ReDim aHoliday(holName.Count - 1, 1)   

    For i = 0 To holName.Count - 1
        aHoliday(i, 0) = holName.Item(i + 1)
        aHoliday(i, 1) = holDate.Item(i + 1)
    Next   

    Holidays = aHoliday   

    Set appOutlook = Nothing
    Set nSpace = Nothing
    Set calFolder = Nothing
    Set calItem = Nothing
    Set filterItems = Nothing
    Set holName = Nothing
    Set holDate = Nothing 

End Function

With the code within the module, you should now add a module. In this module, you will enter de following lines of code:

Function Holidays(InitialDate As String, EndDate As String, _
        Country As String) As Variant
    Dim Holiday As New clsHolidays
    Holidays = Holiday.Holidays(InitialDate, EndDate, Country)
End Function

This will return an array function and, therefore, you should enter it using CTRL+SHIFT+ENTER. The dates I chose to be entered as strings rather than dates. However, you may change that if you wish.

You can now test the function in your spreadsheet:

Picture 1 - Holidays from Outlook's calendar